James Weaver on Quantum Computing and Java

Romain Guy's Magic InfiniteProgressPanel

I've mentioned how simple, elegant and powerful JavaFX Script is.  Here's a perfect example of these three qualities.  A few weeks ago I wanted to show a progress indicator in a multi-tier application that has a rich client developed in JavaFX Script.  Whenever the client is waiting for a response from the server, I wanted to show this progress indicator.

The screenshot above shows the InfiniteProgressPanel widget that I used from the JavaFX Script UI library.  It was invented by Romain Guy, a co-author of the book Filthy Rich Clients.  It is a great alternative to a progress bar due to the fact that you don't have to continually calculate what percent complete the operation is.  This is because the progress bar is circular (and therefore infinite).  In addition, it is very easy to use: You just place the InfiniteProgressPanel in the UI containment hierarchy, and bind its progress attribute to a Boolean variable that is true whenever you want the progress indicator to appear.  Here's the code for this compiled JavaFX Script example:

/*
*  CompiledInfiniteProgress.fx
*
*  Developed 2007 by James L. Weaver (jim.weaver at lat-inc.com)
*  to serve as a compiled JavaFX Script example.
*/

import javafx.ui.*;
import java.lang.System;

Frame {
  var busy = false
  title: "Infinite Progress Panel Demo"
  width: 400
  height: 400
  background: Color.WHITE
  visible: true
  onClose:
    function() {
      System.exit(0);
    }
  content:
    InfiniteProgressPanel {
      progress: bind busy
      content:
        FlowPanel {
          content: [
            Button {
              text: "Get Busy"
              action:
                function() {
                  busy = true;
                  ConfirmDialog {
                    title: "Patience is a Virtue"
                    message: "Simulating a busy condition"
                    visible:true
                    onYes:
                      function() {
                        busy = false
                      }
                  };
                }
            }
          ]
        }
    }
}

Please compile and run this example and try it out for yourself!  When you click the Get Busy button, the confirmation dialog will be displayed and the infinite progress indicator will appear.  When you dismiss the dialog by clicking the OK button, the progress indicator will disappear. 

By the way, the next several posts are going to highlight various UI widgets similar to the way this post does.  I'd like to give you an appreciation of the rich set of widgets available in JavaFX Script, and how easy they are to use.

JavaFX Script Boot Camp Announcement

As a heads-up, I will be offering a JavaFX Script 2.5 day "boot camp" on Wednesday, April 9 through Friday, April 11, 2008 (ending at noon) in Indianapolis, Indiana.  This course is designed to get you quickly up to speed in JavaFX Script application development.  A primary reference for this course is my JavaFX Script book, but the course has its own syllabus which includes material covered in the book as well as up to the minute developments in compiled JavaFX Script. Registration will open soon, and for this pilot class I am accepting 12 students.  The cost of this pilot class will be 900 USD per student. Additional students from the same organization will be 600 USD.  You'll need to bring your laptop computer with the latest versions of the JavaFX Script downloads (which I'll specify in more detail as the class date approaches).  The prerequisite for the class will be the completion of a JavaFX Script programming assignment that I'll post soon to this weblog.  I'm looking forward to teaching this class and hope that you can attend!

More details to follow,
Jim Weaver
JavaFX Script: Dynamic Java Scripting for Rich Internet/Client-side Applications
Immediate eBook (PDF) download available at the book's Apress site

Compiled JavaFX Script Rosetta Stone (in Progress)

As I'm converting the examples and exercises in my JavaFX Script book to compiled JavaFX Script, I'm making note of the kinds of changes required.  I plan to post these notes in a more formal way to the Converting to the New Syntax PlanetJFX Wiki entry that Tom Ball created, but I want to give you a brief synopsis of some notable changes at this point:

• operation and function have been combined into just function.  The body of the function is now supplied at the location in which it is declared (see Converting to New Syntax post).
• attribute initializers and replace triggers are now placed in the attribute declaration, rather than in separate areas (again, see the Converting to New Syntax post). 
• There is a feature in replace triggers that isn't in the Converting to the New Syntax post yet.  This feature enables you to get the original value of the attribute in case you want to veto the replace.

To see examples of the changes noted above, please take a look at my No Need for Setters and Constructors in Compiled JavaFX Script post.  Continuing on:

• named instances (for example white:Color) are now defined as static (class) variables (for example Color.WHITE).  See my Happy New Year post for examples of this.
• Access modifiers (private, protected and public) are respected now.
• Object literals that don't require attributes (e.g. MenuSeparator) require curly braces in compiled JavaFX Script, where interpreted JavaFX Script is more forgiving (doesn't require curly braces).
• Have to explicitly specify object literal names that were implicit in interpreted (like this example using the accelerator attribute of the MenuItem class). The first example works in interpreted JavaFX Script, but the second one is necessary for compiled JavaFX Script:

        MenuItem {
          text: "Place Word Randomly..."
          mnemonic: R
          accelerator: {
            modifier: CTRL
            keyStroke: R
          }
        }


        MenuItem {
          text: "Place Word Randomly..."
          mnemonic: KeyStroke.R
          accelerator: 
            Accelerator {
              modifier: KeyModifier.CTRL
              keyStroke: KeyStroke.R
            }
        }

• Functions in classes that you override in other classes (e.g. CompositeNode) requires explicit return type (e.g. function composeNode():Node)
• Bi-directional binding requires "with inverse" at the end. For example:
  

          TextField {
            value: bind model.firstName with inverse
          }

• The compiler is strict about assigning a Number variable to an Integer variable (because of possible loss of precision).  Use the intValue() function of the Number variable to convert without a compiler error.

Here are some changes in which you can reference the Compiled JavaFX for - Is it an Expression or a Statement post:

• The syntax to declare a sequence is square brackets [] rather than an asterisk *.
• for and foreach have been combined into for, which can be used as a statement or an expression.
• Functions that don't return anything are declared with :Void at the end of the function signature.

Here are a few more changes/additions I'd like to mention as well.

• Compiled JavaFX Script is an expression language, so you can take advantage of features such as sometimes omitting the return statement in a function.  See the Express Yourself in Compiled JavaFX Script post for details.
• The if/else expression in compiled JavaFX Script is just like Java and JavaScript:  parentheses are required around the conditional expression, and curly braces are not required.  Because compiled JavaFX Script is a block expression language, an if/else expression has a value and therefore behaves like the Java ternary operator.  It can also be used as a statement, which behaves like the Java if/else statement.  Please see the Compiled JavaFX if/else - Is it a Statement or an Expression post for details.
• Functions are first-class objects, and closures are a feature of compiled JavaFX Script.  See the Achieving Closure in Compiled JavaFX Script post for details.

I think that you'll enjoy moving over to compiled JavaFX Script (when you're ready -- I'm not rushing you).  It still has some unimplemented features (e.g. insert before/after, and delete predicates in sequences), and some refining to do on the UI side, but it's feeling pretty good right now.  It would be great if you'd begin playing around with it and be part of the JavaFX Compiler community that identifies and reports bugs.  There is an issue tracking system called JIRA that we're using for this purpose.

Regards,
Jim Weaver
JavaFX Script: Dynamic Java Scripting for Rich Internet/Client-side Applications
Immediate eBook (PDF) download available at the book's Apress site

Happy New Year - Formatting in Compiled JavaFX Script

I just want to wish you a Happy New Year, and to show you an example of date formatting in compiled JavaFX Script.  First, here are the screenshots of a few invocations of the program, each one taken after having changed to a different locale on my computer.  Of course, your computer is probably already set to your desired locale, so when you run this program, you should see the word "Happy", followed by the day of the week in your language, followed by the date in your language (of the first day of 2008).

Here's the program, followed by a brief explanation of its formatting aspects:

/*
 *  HappyNewYearFormatting.fx - Example of using formatting
 *                              in compiled JavaFX Script
 *
 *  Developed 2007 by James L. Weaver (jim.weaver at lat-inc.com)
 */
import javafx.ui.*;
import javafx.ui.canvas.*;
import java.lang.System;
import java.text.DateFormat;
import java.util.GregorianCalendar;
  
Frame {
  title: "Happy New Year!"
  width: 500
  height: 100
  background: Color.WHITE
  visible: true
  content:
    Canvas {
      var cal = new GregorianCalendar(2008, 0, 1)
      var df = DateFormat.getDateInstance(DateFormat.LONG)
      content:
        Text {
          font: 
            Font {
              face: FontFace.SANSSERIF
              style: FontStyle.PLAIN
              size: 24
            }
          stroke: Color.RED
          fill: Color.RED
          x: 15
          y: 25
          content: bind "Happy {%tA cal}, {df.format(cal.getTime())}"
        } 
    }
}

Formatting in Compiled JavaFX Script

You can control how numbers and dates are converted to character strings by providing an additional formatting prefix in a String expression. This prefix follows the specification of the Java Formatter class.  In the example above, I'm using the %tA formatting prefix to convert the date to the day of the week in the default locale.  I'm also using the capabilities of the Java DateFormat class to show the month, day and year in the language and order of the default locale.

Please have a happy, healthy, and prosperous 2008,
Jim Weaver
JavaFX Script: Dynamic Java Scripting for Rich Internet/Client-side Applications
Immediate eBook (PDF) download available at the book's Apress site

No Need for Setters and Constructors in Compiled JavaFX Script

To support its simple, declarative programming model, compiled JavaFX Script has some constructs to eliminate the need for setter and constructor methods.  Please take a look at the following example and its console output, and I'll follow up with an explanation of two of these constructs.

/*
 *  TriggersAndPostinit.fx - Example of using a replace trigger
 *                           to eliminate the need for a setter,
 *                           and a postinit block for some
 *                           constructor-related functionality
 *
 *  Developed 2007 by James L. Weaver (jim.weaver at lat-inc.com)
 */

import java.lang.System;

class Vehicle {
  postinit {
    if (numWheels == 18 and sporty) {
      System.out.println("Veto sporty for 18 wheeler!");
      sporty = false;
    }
  }
  attribute model:String;
  attribute numWheels:Integer = 4
    on replace (oldValue) {
      if (numWheels <= 0) {
        System.out.println("{numWheels} wheels not valid, changing to {oldValue}!");
        numWheels = oldValue;
      }
    }
  attribute sporty:Boolean;
  
  public function toString():String {
    return "Model: {model}, Number of wheels: {numWheels}, Sporty: {sporty}"
  }
}

var corvette = 
  Vehicle {
    model: "Corvette"
    numWheels: 4
    sporty: true
  };

System.out.println("{corvette}
");

corvette.numWheels = 0; 

System.out.println("{corvette}
");

var mackTruck = 
  Vehicle {
    model: "Mack truck"
    numWheels: 18
    sporty: true
  };

System.out.println("{mackTruck}
");

Please see previous posts like this one for how to build and run compiled JavaFX Script programs.  Here's the console output when running this program:

Model: Corvette, Number of wheels: 4, Sporty: true

0 wheels not valid, changing to 4!
Model: Corvette, Number of wheels: 4, Sporty: true

Veto sporty for 18 wheeler!
Model: Mack truck, Number of wheels: 18, Sporty: false

Eliminating Setter (Mutator) Methods

In this example, a class named Vehicle is defined, from which we're going to create instances.  One very important role of a setter method is to protect the integrity of the object.  In this example, we don't want the number of wheels on a vehicle to be set to 0 or less.  Traditionally, a setNumWheels() method would be created in which an invalid value would be rejected.  To support the declarative model, compiled JavaFX Script has an on replace trigger that gets invoked whenever the value of an attribute is replaced.  In the example above, note that the on replace block rejects the new value and sets the attribute value back to the former value.  Note that oldValue is an arbitrarily named variable that is local to the on replace block.

Providing Constructor-Related Functionality

After after a new object has been created, and all of its attributes have been assigned their default or explicitly set values, the postinit block (if present) is executed.  This gives you the opportunity to perform functionality, including protecting the integrity of the object, when all of the attribute values are known.  In the example above, an 18-wheeler truck can't be sporty as well (although I've seen some pretty sporty semi-trucks on the road).

Please also note the toString() function in this example.  When you use an object reference in a String, the toString() function is automatically called.  Here, I've overridden the default toString() function to make it easy to print its contents in the desired format.

Oh, by the way, I'm hearing more voices.  Check out this post on Maxa Blog.

As always, if you have any questions, please post a comment.

Regards,
Jim Weaver
JavaFX Script: Dynamic Java Scripting for Rich Internet/Client-side Applications
Immediate eBook (PDF) download available at the book's Apress site

Slides from JavaPolis 2007 JavaFX "Conference Presentation"

In a previous post I gave you a link to the slides from my "JavaFX in Action University Session" at JavaPolis 2007.  Now the slides from my "JavaFX" conference presentation are available in PDF.  This was a shorter, one-hour presentation, that was essentially a subset of the three-hour "University Session".
   

Shortly after this session I was interviewed by Aaron Huston (head of the Java Champions and Java Users Group programs at Sun). I'll notify you when the streaming videos for these sessions become available.

Regards,
Jim Weaver
JavaFX Script: Dynamic Java Scripting for Rich Internet/Client-side Applications
Immediate eBook (PDF) download available at the book's Apress site

Happy Holidays - Compiled JavaFX Script Applet

To wish you Happy Holidays (and if you'll permit me, a very merry Christmas) I wrote this Compiled JavaFX Script Applet (that executes in a browser). 

For fast deployment I used the latest version of Java SE 6 Update 10 (formerly known as Java SE Update N, formerly known as Consumer JRE, formerly known as Prince :-D).  I also used the latest beta version of Firefox (Minefield 3.0 beta), as this is necessary if you want to use the Java SE Update 10 browser plug-in with Firefox.  Check out this video blog by Robert Eckstein for some great information about Java SE Update 10.

The JavaFX Script compiler team is working as we speak on a simple, elegant, way to create JavaFX Applets.  The technique that I used is a short term approach that should not be used as a model for creating JavaFX Script applets beyond just playing around. 

Update March 16, 2008: There are two ways to create JavaFX Script applets, described in detail in the following posts:

• Creating Compiled JavaFX Applets - Method One (of Two)
• Creating Compiled JavaFX Script Applets - Method Two
  

Happy Holidays,
Jim Weaver
JavaFX Script: Dynamic Java Scripting for Rich Internet/Client-side Applications
eBook (PDF) download immediately available at the book's Apress site

Slides from JavaPolis 2007 JavaFX Script in Action "University Session"

Presenting at JavaPolis 2007 in Antwerp, Belgium was a wonderful experience.  I really appreciated the friendly atmosphere, the top-notch organization, and the fact that the sessions were in very comfortable movie theaters! 

The slides for my "JavaFX in Action University Session" are available in PDF now.  The video of the session will be available in the near future, and I'll notify you when that occurs.

Regards,
Jim Weaver
JavaFX Script: Dynamic Java Scripting for Rich Internet/Client-side Applications
eBook (PDF) download immediately available at the book's Apress site

A Compiled JavaFX Script Example with GridPanel and Various Borders - And Leopard Java 6 Preview

Today I'd like to show you an example from my JavaFX Script book that I've ported to compiled JavaFX Script.  It demonstrates the borders available in JavaFX Script, as well as how to use the GridPanel layout widget.  Here's a screenshot of the program's UI:

See a previous post for instructions on obtaining the compiler, keeping in mind that you may want to download the JavaFX Script compiler as well so that you can look at the source code.  This is especially useful for finding constants, for example EtchType.LOWERED in today's example:

/*
 *  BordersExample.fx - An example of the borders available in compiled JavaFX Script
 *
 *  Developed 2007 by James L. Weaver (jim.weaver at lat-inc.com)
 */
package jfx_book;

import javafx.ui.*;
import javafx.ui.canvas.*;

Frame {
  title: "JavaFX Borders"
  width: 500
  height: 500
  visible: true
  content:
    GridPanel {
      rows: 3
      columns: 3
      vgap: 5
      hgap: 5
      cells: [
        Button {
          text: "BevelBorder"
          border: 
            BevelBorder {
            }
        },
        Button {
          text: "EmptyBorder"
          border:
            EmptyBorder {
              top: 20
              left: 20
              bottom: 20
              right: 20
            }
        },
        Button {
          text: "EtchedBorder"
          border: 
            EtchedBorder {
              style: EtchType.LOWERED
            }
        },
        Button {
          text: "LineBorder"
          border: 
            LineBorder {
              thickness: 4
              lineColor: Color.PURPLE
              roundedCorners: true
            }
        },
        Button {
          text: "MatteBorder"
          border:
            MatteBorder {
              matteColor: Color.CORNFLOWERBLUE
              top: 10
              left: 10
              bottom: 10
              right: 10
            }
        },
        Button {
          text: "ShadowedBorder"
          border: 
            ShadowedBorder {
            }
        },
        Button {
          text: "SoftBevelBorder"
          border: 
            SoftBevelBorder {
              style: BevelType.LOWERED
            }
        },
        Button {
          text: "TitledBorder"
          border: 
            TitledBorder {
              title: "Title"
              titlePosition: TitledBorderPosition.BOTTOM
              titleJustification: TitledBorderJustification.CENTER
              titleColor: Color.DARKMAGENTA
            }
        },
        Button {
          text: "CompoundBorder"
          border: 
            CompoundBorder {
              borders: [
                MatteBorder {
                  matteColor: Color.DARKGREEN
                  top: 5
                  left: 5
                  bottom: 5
                  right: 5
                },
                TitledBorder {
                  title: "Title"
                  titleColor: Color.INDIGO
                }
              ]
            }
        },
      ] 
    }
}

Please take this example for a spin, and use it to help you write and submit a compiled JavaFX Script program as instructed in a previous post.

By the way, Apple Java 6 Preview for Leopard is out: http://developer.apple.com/java/

Regards,
Jim Weaver
JavaFX Script: Dynamic Java Scripting for Rich Internet/Client-side Applications
eBook (PDF) download immediately available at the book's Apress site

Creating a Compiled JavaFX Script Program with Multiple FX Source Files

Earlier in this weblog, I showed you an example from my JavaFX Script book that contains multiple FX source files.  Yesterday the JavaFX Script compiler team added the capabilities required to port that example to compiled JavaFX Script.  Please take some time to look at the original example and its explanation at the link provided above.  Then take a look at this ported example, followed by an explanation of how to compile and run it:

HelloJFXModel.fx

/*
 *  HelloJFXModel.fx - The model behind a JavaFX Script "Hello World" style
 *                     example of binding.
 *
 *  Developed 2007 by James L. Weaver (jim.weaver at lat-inc dot com)
 */
package jfx_book;

/**
 * This class serves as the model behind the user interface
 */
class HelloJFXModel {
  attribute greeting:String;
}

HelloJFXBind2.fx

/*
 *  HelloJFXBind2.fx - A Compiled JavaFX Script "Hello World" style example 
 *                     binding to a model that is located in its own file.
 *
 *  Developed 2007 by James L. Weaver (jim.weaver at lat-inc dot com)
 */
package jfx_book;

import javafx.ui.*;
import javafx.ui.canvas.*;

/**
 * This is a JavaFX Script that binds to data from the model.
 */
Frame {
  var hellojfxModel = 
    HelloJFXModel {
      greeting: "Howdy JavaFX Script Developer!"
    }
  title: "JavaFX Script example that binds to a model"
  height: 100
  width: 400
  background: Color.WHITE
  content:
    Canvas {
      content: [
        Text {
          font: 
            Font {
              faceName: "Sans Serif"
              // Example of an attribute with a collection of values
              style: [
                FontStyle.BOLD,
                FontStyle.ITALIC
              ]
              size: 24
            }
          // Put some color into the app
          stroke: Color.RED
          fill: Color.RED
          x: 10
          y: 10
          content: bind  hellojfxModel.greeting
        }
      ]
    }
  visible: true
}

Because these source files are in the jfx_book package, place these files in that directory.  Then navigate to that directory and run the following command:

javafxc HelloJFXModel.fx HelloJFXBind2.fx

Alternatively, you could  use a wildcard:

javafxc *.fx 

After successfully compiling the source files, navigate to the directory in which the top node of the package is located and run the javafx command as usual to execute the program:

javafx jfx_book.HelloJFXBind2

The output of the program should look similar to the interpreted version:

By the way, this and upcoming posts are going to be code-intensive so that you'll feel comfortable writing your own compiled JavaFX Script program in response to the challenge that I gave you yesterday.

Enjoy,
Jim Weaver
JavaFX Script: Dynamic Java Scripting for Rich Internet/Client-side Applications
eBook (PDF) download immediately available at the book's Apress site

Now It's Your Turn to Write a Compiled JavaFX Script Program

In previous posts, I've shown you how to write compiled JavaFX Script programs (for example, The Elephant is Through the Door).  I've also shown you how to obtain the JavaFX Script compiler in order to compile and run your program.  Now I'd like you to have some fun by thinking of an idea for a compiled JavaFX Script program, developing it, and sending it to me so that I can post it for everyone to see.  Here are some guidelines:

• Keep in mind that compiled JavaFX Script is still in development, so you may want to keep your program fairly simple.
• Comment your code well so that when I post the listing, the reader will understand what the code is doing.
• Your program must successfully compile before submitting it.
• In your email, if you'd like your program and source code posted, you'll need to give me permission to do so.
• Of course, please use good judgment regarding the program's content.  I won't post anything that is objectionable (in poor taste, crude, etc.)
• If you have questions while you're developing your program, please post a comment.

Please submit your compiled JavaFX Script program's source to jim.weaver at lat-inc.com, and I'll take care of making it available via Java Web Start and posting the source code.

Good luck,
Jim Weaver
JavaFX Script: Dynamic Java Scripting for Rich Internet/Client-side Applications
eBook (PDF) download immediately available at the book's Apress site